3.016 Problem Set #5.Group, 2010

Now listing the measured conductivity tensor for tin single crystal:

σ = {
{8.55,1.55,0},
{1.55,8.55,0},
{0,0,10.1}
};
σ//MatrixForm

G5-1.1

The electric field is:

Efield=0.1{0,1,0}

Find out the current density vector under the applied electric field:

j020 = σ.Efield

G5-1.2

We need the inverse matrix of σ to compute e-vector from a known j-vector:

invσ = Inverse[σ];
invσ//MatrixForm

Leave off the (10^(-6)), and the answer will be in milli-newtons/charge:

e[n_] := invσ.(n)

e[{1,0,0}]
e[{0,1,0}]
e[{0,0,1}]

Above are the e-vectors for the three cases flowing in x-, y- and z- axis respectively.

G5-1.3

List the unit normal e-vectors:

Ehat[θ_,ϕ_] := {
Cos[ϕ] Cos[θ],
Cos[ϕ] Sin[θ],
Sin[ϕ] 
}

Work out the function α(θ,ϕ):

α[θ_,ϕ_] := Module[
{n,j },
n= Ehat[θ,ϕ];
j = σ .n;
ArcCos[j.n/Norm[j]]
]

Now plot the scalar function α in different ways:

Plot3D[α[θ,ϕ],{θ,-Pi,Pi},{ϕ, 0, 2 Pi},PlotPoints->{50,50}]

ContourPlot[α[θ,ϕ],{ϕ, 0, 2 Pi}, {θ,-Pi,Pi}]

Plot the unit normal e-vectors sphere:

ParametricPlot3D[Ehat[θ,ϕ],{θ,-Pi,Pi},{ϕ, 0, 2 Pi}]

Now we can plot the three dimensional angular relationship between j-vector and e-vector:

anglePlot=ParametricPlot3D[{α[θ,ϕ]Ehat[θ,ϕ]},{θ,-Pi,Pi},{ϕ, 0, 2 Pi}]

Note that in the above figure Ehat (e-vector) gives the direction determined by (θ, ϕ), and α gives the angle value/magnitude along the same direction.

G5-1.4

Find out the eigenvalues and eigenvectors using Eigensystem function:

esys= Eigensystem[σ]

G5-1.5

2 esys[[2,1]]

2 esys[[2,2]]

2 esys[[2,3]]

Show[anglePlot,
Graphics3D[
{
{Red,Cylinder[{-2 esys[[2,1]],2 esys[[2,1]]},.01]},
{Green,Cylinder[{-2 esys[[2,2]],2 esys[[2,2]]},.01]},
{Blue,Cylinder[{-2 esys[[2,3]],2 esys[[2,3]]},.01]}}
]
]

We can see that, for the applied electric filed along the three eigen vectors, the α angle are all zero which means j-vector is parallel to e-vector. This is one way to do this, with direct visualization. There are also other ways to achieve the same conclusion.

G5-1.6

Plot the representation surface in the original coordinate system:

qforig = Simplify[{ex,ey,ez}.σ.{ex,ey,ez}]

ContourPlot3D[qforig==1,{ex,-.4,.4},{ey,-.4,.4},{ez,-.4,.4}]

We will plot the representation surface in the principle coordinate system:

The unit eigenvectors:

esys[[2]]

Transform σ to the principle coordinate system (the eigensystem):

ineig=Chop[(Inverse[Transpose[esys[[2]]]].σ.Transpose[esys[[2]]])]

Work out the representation surface and plot it:

qfeig=Simplify[{ex,ey,ez}.ineig.{ex,ey,ez}]

ContourPlot3D[qfeig==1,{ex,-.4,.4},{ey,-.4,.4},{ez,-.4,.4}]

Note that the size and shape are all the same with that shown earlier when it was not plotted under the principle coordinate system. The eigenvectors are the same with respect to the principle axes and the representation surface, but when the axes rotate these vectors change. The eigenvalues remain the same.

G5-1.7

For cubic systems the conductivity is isotropic:
(({{a, 0, 0}, {0, a, 0}, {0, 0, a}}))
And the surface is a sphere of radius a.

In orthorhombic systems, there are three independent values:
(({{a, 0, 0}, {0, b, 0}, {0, 0, c}}))
And the surface is an ellipsoid with its axes aligned in the x-, y-, and z-directions with lengths a, b, c.

Scaling the coordinate systems by the eigenvalue in each direction, in each case the surface can be mapped onto a sphere:

SphericalPlot3D[1,{θ,-Pi,Pi}, {ϕ,0,2Pi}, AxesLabel-> {"x/a","y/b", "z/c"},BaseStyle-> Large,Ticks-> False]