3.016 Problem Set #4.Group, 2010

G4-1

In this problem, the displacement field near an edge dislocation will be visualized, and its elastic field will be calculated and visualized.

Clear[x,y]

Define r:

r= Sqrt[x^2 + y^2]

Clear[pois]

Note that pois is the Poisson ratio.
Now write the x-displacement field u(x,y):

u  = (b/(2 Pi))(ArcTan[x,y]  + 1/(2(1-pois)) x y/r^2)

Normaliz u by b gives:

uNorm=u/b

Now write the y-displacement field v(x,y):

v = (b/(2 Pi))((1-  2 pois)/(2(1-pois))Log[b/r] +  1/(2(1-pois)) y^2/r^2)

Normaliz v by b gives:

vNorm=v/b

If we let x -> ξ*b, y -> ψ*b, then we can have:

uNormalized=Simplify[uNorm/.{x->ξ*b,y->ψ*b},Assumptions-> b >0]

and

vNormalized=Simplify[vNorm/.{x->ξ*b,y->ψ*b},Assumptions-> b >0]

G4-2

Generate displacement field by an edge dislocation, assuming pois = 1/4 and b=1:

exampleDisplacementField ={uNorm,vNorm}/.{pois-> 1/4,b->1}

exampleDisplacementFieldN ={uNormalized,vNormalized}/.{pois-> 1/4}

Plot the displacement field using vector plot:

VectorPlot[exampleDisplacementField,{x,-6,6},{y,-6,6}]

VectorPlot[exampleDisplacementFieldN,{ξ,-6,6},{ψ,-6,6}]

The region near zero is problematic because of the singularity. 
We'll exclude that region from the plot. 
Here is one way of doing it. This could also be done with PieceWise or with an If.

VectorPlot[exampleDisplacementField,{x,-6,6},{y,-6,6},RegionFunction-> (Norm[{#1,#2}] ≥ 2 &),VectorScale-> 0.75,PlotRange-> {{-6,6},{-6,6}}]

VectorPlot[exampleDisplacementFieldN,{ξ,-6,6},{ψ,-6,6},RegionFunction-> (Norm[{#1,#2}] ≥ 2 &),VectorScale-> 0.75,PlotRange-> {{-6,6},{-6,6}}]

The discontinuity from the extra lattice plane is clearly observable.

G4-3

According to the given definition of the (small) strain components, compute them:

dExx = Simplify[D[u,x],Assumptions-> x ∈ Reals && y ∈ Reals&& b ∈ Reals]

dEyy = Simplify[D[v,y],Assumptions-> x ∈ Reals && y ∈ Reals&& b ∈ Reals]

dExy = Simplify[(D[u,y] + D[v,x])/2, Assumptions-> x ∈ Reals && y ∈ Reals&& b ∈ Reals]

Note that both x and y should be real numbers. Make sure we take those into the assumptions for simplification.

G4-4

Here it is the relationship between Young's modulus (Y) and shear modulus (G):

Y = 2 G( 1 + pois)

List the six equations that relate between stress and strain components:

eq1 = exx == (sxx - pois(syy + szz))/Y

eq2 =  eyy == (syy - pois(sxx + szz))/Y

eq3 =  ezz == (szz - pois(sxx + syy))/Y

eq4 = eyz == (1 + pois) syz/Y

eq5 = ezx == (1 + pois) szx/Y

eq6 = exy == (1 + pois) sxy/Y

Solve for stress components:

sols = Solve[{eq1,eq2,eq3,eq4,eq5,eq6},{sxx,syy,szz,syz,szx,sxy}]//Simplify

Substitute strains as computed in G4-3:

tmp = Simplify[sols/.{exx-> dExx,eyy-> dEyy, ezz-> 0, ezx-> 0, eyz-> 0, exy-> dExy}]

These are the expressions of stresses found in text books for an edge dislocation .

G4-5

Take a particular example for stresses:

sigxy=(sxy/.tmp)[[1]]/.{b->1,G->1,pois->1/4}

sigxx=(sxx/.tmp)[[1]]/.{b->1,G->1,pois->1/4}

sigyy=(syy/.tmp)[[1]]/.{b->1,G->1,pois->1/4}

sigzz=(szz/.tmp)[[1]]/.{b->1,G->1,pois->1/4}

hydroPressure=Simplify[-(sigxx+sigyy+sigzz)/3]

Now visualize stress field of sxx:

ContourPlot[sigxx,{x,-15,15},{y,-15,15},RegionFunction-> (Norm[{#1,#2}] ≥ 2&),ContourLabels->True]

Now visualize stress field of sxy:

ContourPlot[sigxy,{x,-30,30},{y,-30,30},RegionFunction-> (Norm[{#1,#2}] ≥ 2&),ContourLabels->True,ColorFunction->"Rainbow"]

Now visualize stress field of P:

ContourPlot[hydroPressure,{x,-10,10},{y,-10,10},RegionFunction-> (Norm[{#1,#2}] ≥ 2&),ContourLabels->True,ColorFunction->"DarkRainbow"]